JoinNode

Warning! This page documents an old version of Kapacitor, which is no longer actively developed. Kapacitor v1.3 is the most recent stable version of Kapacitor.

Joins the data from any number of nodes. As each data point is received from a parent node it is paired with the next data points from the other parent nodes with a matching timestamp. Each parent node contributes at most one point to each joined point. A tolerance can be supplied to join points that do not have perfectly aligned timestamps. Any points that fall within the tolerance are joined on the timestamp. If multiple points fall within the same tolerance window than they are joined in the order they arrive.

Aliases are used to prefix all fields from the respective nodes.

The join can be an inner or outer join, see the JoinNode.Fill property.

Example:

    var errors = stream
        |from()
            .measurement('errors')
    var requests = stream
        |from()
            .measurement('requests')
    // Join the errors and requests streams
    errors
        |join(requests)
            // Provide prefix names for the fields of the data points.
            .as('errors', 'requests')
            // points that are within 1 second are considered the same time.
            .tolerance(1s)
            // fill missing values with 0, implies outer join.
            .fill(0.0)
            // name the resulting stream
            .streamName('error_rate')
        // Both the "value" fields from each parent have been prefixed
        // with the respective names 'errors' and 'requests'.
        |eval(lambda: "errors.value" / "requests.value")
           .as('rate')
        ...

In the above example the errors and requests streams are joined and then transformed to calculate a combined field.

Index

Properties

Chaining Methods

Properties

Property methods modify state on the calling node. They do not add another node to the pipeline, and always return a reference to the calling node. Property methods are marked using the . operator.

As

Prefix names for all fields from the respective nodes. Each field from the parent nodes will be prefixed with the provided name and a '.'. See the example above.

The names cannot have a dot '.' character.

node.as(names ...string)

Delimiter

The delimiter for the field name prefixes. Can be the empty string.

node.delimiter(value string)

Fill

Fill the data. The fill option implies the type of join: inner or full outer Options are:

  • none - (default) skip rows where a point is missing, inner join.
  • null - fill missing points with null, full outer join.
  • Any numerical value - fill fields with given value, full outer join.

When using a numerical or null fill, the fields names are determined by copying the field names from another point. This doesn't work well when different sources have different field names. Use the DefaultNode and DeleteNode to finalize the fill operation if necessary.

Example:

    var maintlock = stream
        |from()
            .measurement('maintlock')
            .groupBy('service')
    var requests = stream
        |from()
            .measurement('requests')
            .groupBy('service')
    // Join the maintlock and requests streams
    // The intent it to drop any points in maintenance mode.
    maintlock
        |join(requests)
            // Provide prefix names for the fields of the data points.
            .as('maintlock', 'requests')
            // points that are within 1 second are considered the same time.
            .tolerance(1s)
            // fill missing fields with null, implies outer join.
            // a better default per field will be set later.
            .fill('null')
            // name the resulting stream.
            .streamName('requests')
        |default()
            // default maintenance mode to false, overwriting the null value if present.
            .field('maintlock.mode', false)
            // default the requests to 0, again overwriting the null value if present.
            .field('requests.value', 0.0)
        // drop any points that are in maintenance mode.
        |where(lambda: "maintlock.mode")
        |...
node.fill(value interface{})

On

Join on a subset of the group by dimensions. This is a special case where you want a single point from one parent to join with multiple points from a different parent.

For example given two measurements:

  1. building_power (a single value) – tagged by building, value is the total power consumed by the building.
  2. floor_power (multiple values) – tagged by building and floor, values are the total power consumed by each floor.

You want to calculate the percentage of the total building power consumed by each floor. Since you only have one point per building you need it to join multiple times with the points from each floor. By defining the on dimensions as building we are saying that we want points that only have the building tag to be joined with more specifc points that more tags, in this case the floor tag. In other words while we have points with tags building and floor we only want to join on the building tag.

Example:

    var building = stream
        |from()
            .measurement('building_power')
            .groupBy('building')
    var floor = stream
        |from()
            .measurement('floor_power')
            .groupBy('building', 'floor')
    building
        |join(floor)
            .as('building', 'floor')
            .on('building')
        |eval(lambda: "floor.value" / "building.value")
            ... // Values here are grouped by 'building' and 'floor'
node.on(dims ...string)

StreamName

The name of this new joined data stream. If empty the name of the left parent is used.

node.streamName(value string)

Tolerance

The maximum duration of time that two incoming points can be apart and still be considered to be equal in time. The joined data point's time will be rounded to the nearest multiple of the tolerance duration.

node.tolerance(value time.Duration)

Chaining Methods

Chaining methods create a new node in the pipeline as a child of the calling node. They do not modify the calling node. Chaining methods are marked using the | operator.

Alert

Create an alert node, which can trigger alerts.

node|alert()

Returns: AlertNode

Bottom

Select the bottom num points for field and sort by any extra tags or fields.

node|bottom(num int64, field string, fieldsAndTags ...string)

Returns: InfluxQLNode

Combine

Combine this node with itself. The data are combined on timestamp.

node|combine(expressions ...ast.LambdaNode)

Returns: CombineNode

Count

Count the number of points.

node|count(field string)

Returns: InfluxQLNode

CumulativeSum

Compute a cumulative sum of each point that is received. A point is emitted for every point collected.

node|cumulativeSum(field string)

Returns: InfluxQLNode

Deadman

Helper function for creating an alert on low throughput, a.k.a. deadman's switch.

  • Threshold – trigger alert if throughput drops below threshold in points/interval.
  • Interval – how often to check the throughput.
  • Expressions – optional list of expressions to also evaluate. Useful for time of day alerting.

Example:

    var data = stream
        |from()...
    // Trigger critical alert if the throughput drops below 100 points per 10s and checked every 10s.
    data
        |deadman(100.0, 10s)
    //Do normal processing of data
    data...

The above is equivalent to this Example:

    var data = stream
        |from()...
    // Trigger critical alert if the throughput drops below 100 points per 10s and checked every 10s.
    data
        |stats(10s)
            .align()
        |derivative('emitted')
            .unit(10s)
            .nonNegative()
        |alert()
            .id('node \'stream0\' in task \'{{ .TaskName }}\'')
            .message('{{ .ID }} is {{ if eq .Level "OK" }}alive{{ else }}dead{{ end }}: {{ index .Fields "emitted" | printf "%0.3f" }} points/10s.')
            .crit(lambda: "emitted" <= 100.0)
    //Do normal processing of data
    data...

The id and message alert properties can be configured globally via the 'deadman' configuration section.

Since the AlertNode is the last piece it can be further modified as usual. Example:

    var data = stream
        |from()...
    // Trigger critical alert if the throughput drops below 100 points per 10s and checked every 10s.
    data
        |deadman(100.0, 10s)
            .slack()
            .channel('#dead_tasks')
    //Do normal processing of data
    data...

You can specify additional lambda expressions to further constrain when the deadman's switch is triggered. Example:

    var data = stream
        |from()...
    // Trigger critical alert if the throughput drops below 100 points per 10s and checked every 10s.
    // Only trigger the alert if the time of day is between 8am-5pm.
    data
        |deadman(100.0, 10s, lambda: hour("time") >= 8 AND hour("time") <= 17)
    //Do normal processing of data
    data...
node|deadman(threshold float64, interval time.Duration, expr ...ast.LambdaNode)

Returns: AlertNode

Default

Create a node that can set defaults for missing tags or fields.

node|default()

Returns: DefaultNode

Delete

Create a node that can delete tags or fields.

node|delete()

Returns: DeleteNode

Derivative

Create a new node that computes the derivative of adjacent points.

node|derivative(field string)

Returns: DerivativeNode

Difference

Compute the difference between points independent of elapsed time.

node|difference(field string)

Returns: InfluxQLNode

Distinct

Produce batch of only the distinct points.

node|distinct(field string)

Returns: InfluxQLNode

Elapsed

Compute the elapsed time between points

node|elapsed(field string, unit time.Duration)

Returns: InfluxQLNode

Eval

Create an eval node that will evaluate the given transformation function to each data point. A list of expressions may be provided and will be evaluated in the order they are given. The results are available to later expressions.

node|eval(expressions ...ast.LambdaNode)

Returns: EvalNode

First

Select the first point.

node|first(field string)

Returns: InfluxQLNode

Flatten

Flatten points with similar times into a single point.

node|flatten()

Returns: FlattenNode

GroupBy

Group the data by a set of tags.

Can pass literal * to group by all dimensions. Example:

    |groupBy(*)
node|groupBy(tag ...interface{})

Returns: GroupByNode

HoltWinters

Compute the holt-winters forecast of a data set.

node|holtWinters(field string, h int64, m int64, interval time.Duration)

Returns: InfluxQLNode

HoltWintersWithFit

Compute the holt-winters forecast of a data set. This method also outputs all the points used to fit the data in addition to the forecasted data.

node|holtWintersWithFit(field string, h int64, m int64, interval time.Duration)

Returns: InfluxQLNode

HttpOut

Create an HTTP output node that caches the most recent data it has received. The cached data are available at the given endpoint. The endpoint is the relative path from the API endpoint of the running task. For example, if the task endpoint is at /kapacitor/v1/tasks/&lt;task_id&gt; and endpoint is top10, then the data can be requested from /kapacitor/v1/tasks/&lt;task_id&gt;/top10.

node|httpOut(endpoint string)

Returns: HTTPOutNode

InfluxDBOut

Create an influxdb output node that will store the incoming data into InfluxDB.

node|influxDBOut()

Returns: InfluxDBOutNode

Join

Join this node with other nodes. The data are joined on timestamp.

node|join(others ...Node)

Returns: JoinNode

K8sAutoscale

Create a node that can trigger autoscale events for a kubernetes cluster.

node|k8sAutoscale()

Returns: K8sAutoscaleNode

Last

Select the last point.

node|last(field string)

Returns: InfluxQLNode

Log

Create a node that logs all data it receives.

node|log()

Returns: LogNode

Max

Select the maximum point.

node|max(field string)

Returns: InfluxQLNode

Mean

Compute the mean of the data.

node|mean(field string)

Returns: InfluxQLNode

Median

Compute the median of the data. Note, this method is not a selector, if you want the median point use .percentile(field, 50.0).

node|median(field string)

Returns: InfluxQLNode

Min

Select the minimum point.

node|min(field string)

Returns: InfluxQLNode

Mode

Compute the mode of the data.

node|mode(field string)

Returns: InfluxQLNode

MovingAverage

Compute a moving average of the last window points. No points are emitted until the window is full.

node|movingAverage(field string, window int64)

Returns: InfluxQLNode

Percentile

Select a point at the given percentile. This is a selector function, no interpolation between points is performed.

node|percentile(field string, percentile float64)

Returns: InfluxQLNode

Sample

Create a new node that samples the incoming points or batches.

One point will be emitted every count or duration specified.

node|sample(rate interface{})

Returns: SampleNode

Shift

Create a new node that shifts the incoming points or batches in time.

node|shift(shift time.Duration)

Returns: ShiftNode

Spread

Compute the difference between min and max points.

node|spread(field string)

Returns: InfluxQLNode

Stats

Create a new stream of data that contains the internal statistics of the node. The interval represents how often to emit the statistics based on real time. This means the interval time is independent of the times of the data points the source node is receiving.

node|stats(interval time.Duration)

Returns: StatsNode

Stddev

Compute the standard deviation.

node|stddev(field string)

Returns: InfluxQLNode

Sum

Compute the sum of all values.

node|sum(field string)

Returns: InfluxQLNode

Top

Select the top num points for field and sort by any extra tags or fields.

node|top(num int64, field string, fieldsAndTags ...string)

Returns: InfluxQLNode

Union

Perform the union of this node and all other given nodes.

node|union(node ...Node)

Returns: UnionNode

Where

Create a new node that filters the data stream by a given expression.

node|where(expression ast.LambdaNode)

Returns: WhereNode

Window

Create a new node that windows the stream by time.

NOTE: Window can only be applied to stream edges.

node|window()

Returns: WindowNode