Documentation

Write data from InfluxDB OSS to InfluxDB Cloud

To write data from InfluxDB OSS to InfluxDB Cloud, use the Flux to() or experimental.to() functions. Write data once with a single query execution or use InfluxDB tasks to routinely write data to InfluxDB Cloud.

Replicate writes to InfluxDB OSS to InfluxDB Cloud

To replicate all writes to an InfluxDB OSS instance to an InfluxDB Cloud instance, use InfluxDB replication streams.

InfluxDB Cloud rate limits

Write requests to InfluxDB Cloud are subject to the rate limits associated with your InfluxDB Cloud pricing plan.

  1. Query data from InfluxDB OSS.

  2. (Optional) Filter or process data to write to InfluxDB Cloud.

  3. Use to or experimental.to to write data to InfluxDB Cloud. For most use cases, to() is the correct function to use, but depending on the structure of the data you’re writing, experimental.to may be required.

    Use the following guidelines:

    • to(): Use to write data in field keys to the _field column and field values to the _value column.

    • experimental.to(): Use to write data in column names to corresponding field keys and column values to field values.

    See input and output examples for to() functions.

  4. Provide the following parameters to either function:

    • bucket: InfluxDB Cloud bucket to write to
    • host: InfluxDB Cloud region URL
    • org: InfluxDB Cloud organization
    • token: InfluxDB Cloud API Token
  5. (Recommended) To keep your raw API token out of queries, store your InfluxDB Cloud API token as an InfluxDB secret in your InfluxDB OSS instance and use secrets.get() to retrieve the secret value as shown in the following example (select the function you’re using to see the correct format):

import "influxdata/influxdb/secrets"

cloudToken = secrets.get(key: "INFLUX_CLOUD_API_TOKEN")

from(bucket: "example-oss-bucket")
    |> range(start: -10m)
    |> filter(fn: (r) => r._measurement == "example-measurement")
    |> to(
        bucket: "example-cloud-bucket",
        host: "https://cloud2.influxdata.com",
        org: "example-org",
        token: cloudToken,
    )
import "experimental"
import "influxdata/influxdb/secrets"

cloudToken = secrets.get(key: "INFLUX_CLOUD_API_TOKEN")

from(bucket: "example-oss-bucket")
    |> range(start: -10m)
    |> filter(fn: (r) => r._measurement == "example-measurement")
    |> pivot(rowKey: ["_time"], columnKey: ["_field"], valueColumn: "_value")
    |> experimental.to(
        bucket: "example-cloud-bucket",
        host: "https://cloud2.influxdata.com",
        org: "example-org",
        token: cloudToken,
    )

Input and output data for to() functions

  • to() requires _time, _measurement, _field, and _value columns.
  • to() writes all other columns as tags where the column name is the tag key and the column value is the tag value.

Input data

_time_measurementexampleTag_field_value
2021-01-01T00:00:00Zexample-mAtemp80.0
2021-01-01T00:01:00Zexample-mAtemp80.3
2021-01-01T00:02:00Zexample-mAtemp81.1
_time_measurementexampleTag_field_value
2021-01-01T00:00:00Zexample-mArpm4023
2021-01-01T00:01:00Zexample-mArpm4542
2021-01-01T00:02:00Zexample-mArpm4901

Output line protocol

example-m,exampleTag=A temp=80.0,rpm=4023i 1609459200000000000
example-m,exampleTag=A temp=80.3,rpm=4542i 1609459260000000000
example-m,exampleTag=A temp=81.1,rpm=4901i 1609459320000000000
  • experimental.to() requires _time and _measurement columns.
  • Columns in the group key (other than _measurement) are parsed as tags where the column name is the tag key and the column value is the tag value.
  • Columns not in the group key (other than _time_) are parsed as fields where the column name is the field key and the column value is the field value.

Input data

Group key = [_measurement, exampleTag]

_time_measurementexampleTagtemprpm
2021-01-01T00:00:00Zexample-mA80.04023
2021-01-01T00:01:00Zexample-mA80.34542
2021-01-01T00:02:00Zexample-mA81.14901

Output line protocol

example-m,exampleTag=A temp=80.0,rpm=4023i 1609459200000000000
example-m,exampleTag=A temp=80.3,rpm=4542i 1609459260000000000
example-m,exampleTag=A temp=81.1,rpm=4901i 1609459320000000000

Examples

Downsample and write data to InfluxDB Cloud

import "influxdata/influxdb/secrets"

cloudToken = secrets.get(key: "INFLUX_CLOUD_API_TOKEN")

from(bucket: "example-oss-bucket")
    |> range(start: -10m)
    |> filter(fn: (r) => r._measurement == "example-measurement")
    |> aggregateWindow(every: 1m, fn: last)
    |> to(
        bucket: "example-cloud-bucket",
        host: "https://cloud2.influxdata.com",
        org: "example-org",
        token: cloudToken,
    )

Write min, max, and mean values to InfluxDB Cloud

import "influxdata/influxdb/secrets"

cloudToken = secrets.get(key: "INFLUX_CLOUD_API_TOKEN")

data = from(bucket: "example-oss-bucket")
    |> range(start: -30m)
    |> filter(fn: (r) => r._measurement == "example-measurement")

min = data |> aggregateWindow(every: 10m, fn: min) |> map(fn: (r) => ({ r with _field: "{$r._field}_min" }))
max = data |> aggregateWindow(every: 10m, fn: max) |> map(fn: (r) => ({ r with _field: "{$r._field}_max" }))
mean = data |> aggregateWindow(every: 10m, fn: mean) |> map(fn: (r) => ({ r with _field: "{$r._field}_mean" }))

union(tables: [min, max, mean])
    |> to(
        bucket: "example-cloud-bucket",
        host: "https://cloud2.influxdata.com",
        org: "example-org",
        token: cloudToken,
    )

Automate writing data from InfluxDB OSS to InfluxDB Cloud

To automatically and routinely write data from InfluxDB OSS to InfluxDB Cloud, create a task in your InfluxDB OSS instance that regularly queries, processes, and writes data to InfluxDB Cloud.

import "influxdata/influxdb/tasks"

option task = {name: "Downsample to InfluxDB Cloud", every: 1h}

from(bucket: "example-oss-bucket")
    |> range(start: -10m)
    |> filter(fn: (r) => r._measurement == "example-measurement")
    |> aggregateWindow(every: 1m, fn: last)
    |> to(
        bucket: "example-cloud-bucket",
        host: "https://cloud2.influxdata.com",
        org: "example-org",
        token: cloudToken,
    )

Was this page helpful?

Thank you for your feedback!


Set your InfluxDB URL

Linux Package Signing Key Rotation

All signed InfluxData Linux packages have been resigned with an updated key. If using Linux, you may need to update your package configuration to continue to download and verify InfluxData software packages.

For more information, see the Linux Package Signing Key Rotation blog post.

InfluxDB Cloud backed by InfluxDB IOx

All InfluxDB Cloud organizations created on or after January 31, 2023 are backed by the new InfluxDB IOx storage engine. Check the right column of your InfluxDB Cloud organization homepage to see which InfluxDB storage engine you’re using.

If powered by IOx, this is the correct documentation.

If powered by TSM, see the TSM-based InfluxDB Cloud documentation.

InfluxDB Cloud backed by InfluxDB TSM

All InfluxDB Cloud organizations created on or after January 31, 2023 are backed by the new InfluxDB IOx storage engine which enables nearly unlimited series cardinality and SQL query support. Check the right column of your InfluxDB Cloud organization homepage to see which InfluxDB storage engine you’re using.

If powered by TSM, this is the correct documentation.

If powered by IOx, see the IOx-based InfluxDB Cloud documentation.

State of the InfluxDB Cloud (IOx) documentation

The new documentation for InfluxDB Cloud backed by InfluxDB IOx is a work in progress. We are adding new information and content almost daily. Thank you for your patience!

If there is specific information you’re looking for, please submit a documentation issue.