Work with integers

An integer type represents a signed 64-bit integer.

Type name: int
Min value: -9223372036854775808
Max value: 9223372036854775807

• Integer syntax
• Convert data types to integers
• Operate on integers

Integer syntax

An integer literal contains one or more digits (0-9) optionally preceded by - to indicate a negative number. -0 is equivalent to 0 and is not a negative number.

0
2
1254
-1254

Convert data types to integers

Use the int() function to convert the following basic types to integers:

• string: returns the integer equivalent of the numeric string ([0-9])
• bool: returns 1 for true or 0 for false
• duration: returns the number of nanoseconds in the duration
• time: returns the equivalent nanosecond epoch timestamp
• float: truncates the float value at the decimal
• uint: returns the integer equivalent of the unsigned integer

int(v: "123")
// 123

int(v: true)
// Returns 1

int(v: 1d3h24m)
// Returns 98640000000000

int(v: 2021-01-01T00:00:00Z)
// Returns 1609459200000000000

int(v: 12.54)
// Returns 12

import "math"

int(v: math.round(x: 12.54))
// Returns 13

Convert a hexadecimal string to an integer

To convert a hexadecimal string representation of a number to an integer:

1. Import the contrib/bonitoo-io/hex package.
2. Use hex.int() to convert the hexadecimal string to an integer.

import "contrib/bonitoo-io/hex"

hex.int(v: "1e240")
// Returns 123456

Convert columns to integers

Flux lets you iterate over rows in a stream of tables and convert columns to integers.

To convert the _value column to integers, use the toInt() function.

data
    |> toInt()

To convert any column to integers:

1. Use map() to iterate over and rewrite rows.
2. Use int() to convert columns values to integers.

data
    |> map(fn: (r) => ({ r with uid: int(v: r.uid) }))

Operate on integers

• Perform arithmetic operations on integers
• Perform bitwise operations on integers
• Compare integers

Perform arithmetic operations on integers

To perform operations like adding, subtracting, multiplying, or dividing integers, use Flux arithmetic operators. Operands must be the same type. The operation returns an integer.

1 + 45
// Returns 46

1 - 45
// Returns -44

12 * 100
// Returns 1200

100 / 200
// Returns 0

10 ^ 2
// Returns 100

Perform bitwise operations on integers

Use the experimental/bitwise package to perform bitwise operations on integers.

import "experimental/bitwise"

bitwise.sand(a: 12, b: 21)
// Returns 4

bitwise.sor(a: 12, b: 21)
// Returns 29

bitwise.sxor(a: 12, b: 21)
// Returns 25

bitwise.sclear(a: 12, b: 21)
// Returns 8

bitwise.snot(a: 12)
// Returns -13

bitwise.slshift(a: 12, b: 21)
// Returns 25165824

bitwise.srshift(a: 21, b: 4)
// Returns 1

Compare integers

Use Flux comparison operators to compare integers. Operands must be the same type. The operation returns a boolean.

12345600 == 12345601
// Returns false

2 > -2
// Returns true